*******************************************************************************
* Transmission line subcircuit for 22 Awg (from ITT)
* Jim Hagerman, 1991

* Call by using:  Xxxxxx n1 n2 n3 n4 n5 n6 22awg

* The nodes are:  n1 = + input
*                 n2 = - input
*                 n3 = + output
*                 n4 = - output
*                 n5 = + feet voltage
*                 n6 = - feet voltage

.subckt 22awg 1 2 3 4 16 17

.model rline res(r=33.71m tc1=0.004)   ; R/ft
.model lline ind(l=164.8n)  ; L/ft
.model cline cap(c=15.53p)  ; C/ft
.model gline res(r=4.44G)   ; R*ft = G/ft

   rin 16 17 1G

   xz1 16 17 7 1 5 var_z
      rz1 7 8 rline 0.25
      Lz1 8 0 Lline 0.25

   xz2 16 17 9 5 3 var_z
      rz2 9 10 rline 0.25
      Lz2 10 0 Lline 0.25

   xz3 16 17 11 2 6 var_z
      rz3 11 12 rline 0.25
      Lz3 12 0 Lline 0.25

   xz4 16 17 13 6 4 var_z
      rz4 13 14 rline 0.25
      Lz4 14 0 Lline 0.25

   xy1 16 17 15 5 6 var_y
      ry1 15 0 gline 1.0
      cy1 15 0 cline 1.0

.ends 22awg

*******************************************************************************
* Subcircuit for variable admittance
* Yout = Yin * Vc; or Zout = Zin / Vc

* Call by using:  Xxxxxx n1 n2 n3 n4 VAR_Y

* The nodes are:  n1 = + control voltage
*                 n2 = - control voltage
*                 n3 = reference admittance (other side to gnd)
*                 n4 = + output
*                 n5 = - output

.subckt var_y 1 2 3 4 5

   ecopy  3 6 poly(2) (1,2) (4,5) 0 0 0 0 1
   fout   4 5 vsense 1
   rin    1 2 1G
   vsense 0 6 0

.ends var_y

*******************************************************************************
* Subcircuit for variable impedance
* Zout = Zin * Vc

* Call by using:  Xxxxxx n1 n2 n3 n4 n5 VAR_Z

* The nodes are:  1 = + control voltage
*                 2 = - control voltage
*                 3 = reference impedance (other side to gnd)
*                 4 = + output
*                 5 = - output

.subckt var_z 1 2 3 4 5

   eout   4 6 poly(2) (1,2) (3,0) 0 0 0 0 1
   fcopy  0 3 vsense 1
   rin    1 2 1G
   vsense 6 5 0

.ends var_z